Oleks
4e2bb71ed5
ci/woodpecker/push/woodpecker Pipeline failed
- packages/xontribs.nix: xontrib-prompt-starship, -broot, -term-integrations wheels for use with `programs.xonsh.extraPackages` (or xonsh.override) - packages/hyprspace.nix + hyprspace flake input (flake=false): rebuild plugin against the consumer's hyprland; exposed via overlays.hyprspace - overlays/gcc15-fixes.nix: hotdoc/kitty/libsecret/xdg-desktop-portal/afdko workarounds so fleet nodes on the same pin can opt in with one line - flake.nix: lift overlays out of eachSystem to the root (overlays.default was previously nested per-system, which doesn't match flake schema)
44 lines
1.6 KiB
Nix
44 lines
1.6 KiB
Nix
# Narrow fixes for packages that fail under the fleet's pinned nixpkgs
|
|
# with GCC 15 / current upstream breakage. Remove entries as upstream fixes
|
|
# land so consumers can drop them on the next pin bump.
|
|
final: prev: {
|
|
# hotdoc's bundled cmark declares `project(cmark VERSION 0.28.3)` without
|
|
# LANGUAGES, which makes CMake probe CXX; GCC 15 fails the probe. Adding
|
|
# LANGUAGES C skips the CXX check.
|
|
hotdoc = prev.hotdoc.overrideAttrs (old: {
|
|
postPatch = (old.postPatch or "") + ''
|
|
substituteInPlace cmark/CMakeLists.txt \
|
|
--replace-fail "project(cmark VERSION 0.28.3)" "project(cmark VERSION 0.28.3 LANGUAGES C)"
|
|
'';
|
|
});
|
|
|
|
# kitty's bundled base64 lib has incompatible pointer types that GCC 15
|
|
# promotes from warning to error.
|
|
kitty = prev.kitty.overrideAttrs (old: {
|
|
env = (old.env or { }) // {
|
|
NIX_CFLAGS_COMPILE = (old.env.NIX_CFLAGS_COMPILE or "") + " -Wno-error=incompatible-pointer-types";
|
|
};
|
|
});
|
|
|
|
# Skip D-Bus-dependent checks that fail under remote-builder sandboxes.
|
|
libsecret = prev.libsecret.overrideAttrs (_: {
|
|
doCheck = false;
|
|
});
|
|
xdg-desktop-portal = prev.xdg-desktop-portal.overrideAttrs (_: {
|
|
doCheck = false;
|
|
});
|
|
|
|
# afdko has two pre-existing test failures that block
|
|
# nototools → noto-fonts-color-emoji.
|
|
pythonPackagesExtensions = (prev.pythonPackagesExtensions or [ ]) ++ [
|
|
(pyFinal: pyPrev: {
|
|
afdko = pyPrev.afdko.overrideAttrs (old: {
|
|
disabledTests = (old.disabledTests or [ ]) ++ [
|
|
"test_non_varying_glyphs_bug356"
|
|
"test_ufo_contentsplist_parsing"
|
|
];
|
|
});
|
|
})
|
|
];
|
|
}
|